Al utilizar una fórmula, puede mostrar el día de la semana para los valores de fecha.

• Coloque un campo "Fecha" o "Fecha y hora" en el formulario de la aplicación.
  Especifique el código de campo del campo ("Fecha" para un campo "Fecha", o "Fecha_y_Hora" para un campo "Fecha y hora").
• Coloque un campo de "Texto" en el formulario. La configuración del código de campo es opcional.
• En Ajustes varios, establezca un valor que sea mayor o igual a 1 para Número de decimales a redondear.

Para obtener más detalles, consulte las páginas siguientes.
Descripción general de los códigos de campo
Establecimiento de dígitos significativos de números y método Redondeo

En el cuadro de diálogo de configuración del campo "Texto", seleccione Calcular automáticamente e ingrese una de las siguientes fórmulas.
La fórmula que se debe configurar para el campo "Texto" varía según si el otro campo ubicado en el formulario de la aplicación es un campo "Fecha" o un campo "Fecha y hora".

IF( ( ( (Date / 60 / 60 / 24) - 0) / 7 ) - ROUNDUP(( ( (Date / 60 / 60 / 24) - 0) / 7 ) , 0) = 0 , "Thursday",
  IF( ( ( (Date / 60 / 60 / 24) - 1) / 7 ) - ROUNDUP(( ( (Date / 60 / 60 / 24) - 1) / 7 ) , 0) = 0 , "Friday",
    IF( ( ( (Date / 60 / 60 / 24) - 2) / 7 ) - ROUNDUP(( ( (Date / 60 / 60 / 24) - 2) / 7 ) , 0) = 0 , "Saturday",
      IF( ( ( (Date / 60 / 60 / 24) - 3) / 7 ) - ROUNDUP(( ( (Date / 60 / 60 / 24) - 3) / 7 ) , 0) = 0 , "Sunday",
        IF( ( ( (Date / 60 / 60 / 24) - 4) / 7 ) - ROUNDUP(( ( (Date / 60 / 60 / 24) - 4) / 7 ) , 0) = 0 , "Monday",
          IF( ( ( (Date / 60 / 60 / 24) - 5) / 7 ) - ROUNDUP(( ( (Date / 60 / 60 / 24) - 5) / 7 ) , 0) = 0 , "Tuesday",
            IF( ( ( (Date / 60 / 60 / 24) - 6) / 7 ) - ROUNDUP(( ( (Date / 60 / 60 / 24) - 6) / 7 ) , 0) = 0 , "Wednesday","N/A"
            )
          )
        )
      )
    )
  )
)

IF( ( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24) ) - 0) / 7 ) - ROUNDUP(( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24)) - 0) / 7 ) , 0) = 0 , "Thursday",
  IF( ( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24) ) - 1) / 7 ) - ROUNDUP(( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24)) - 1) / 7 ) , 0) = 0 , "Friday",
    IF( ( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24) ) - 2) / 7 ) - ROUNDUP(( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24)) - 2) / 7 ) , 0) = 0 , "Saturday",
      IF( ( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24) ) - 3) / 7 ) - ROUNDUP(( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24)) - 3) / 7 ) , 0) = 0 , "Sunday",
        IF( ( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24) ) - 4) / 7 ) - ROUNDUP(( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24)) - 4) / 7 ) , 0) = 0 , "Monday",
          IF( ( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24) ) - 5) / 7 ) - ROUNDUP(( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24)) - 5) / 7 ) , 0) = 0 , "Tuesday",
            IF( ( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24) ) - 6) / 7 ) - ROUNDUP(( ( (ROUNDDOWN((Date_and_Time+(60 * 60 * 9))/ 60 / 60 / 24)) - 6) / 7 ) , 0) = 0 , "Wednesday","N/A"
            )
          )
        )
      )
    )
  )
)

Las fórmulas en Kintone tratan los valores de los campos "Fecha" y "Fecha y hora" como tiempo Unix, que es el número de segundos transcurridos desde las 00:00 UTC (Hora Universal Coordinada) de 1970-1-1.

Para obtener más detalles, consulte la página siguiente.
Cómo se tratan los valores en Campos de fecha, hora y fecha y hora

En las fórmulas de esta página, el valor de fecha ingresado en un campo se convierte en la cantidad de días transcurridos desde la época Unix y luego se calcula. El día de la semana que corresponde a un valor de fecha se muestra utilizando el concepto de dividir la cantidad de días transcurridos desde la época Unix por 7 (la cantidad de días de una semana) y luego determinar el día de la semana en función del resto.

• Examples:
  • Si ingresa el 1 de abril de 2021:
    El número de días transcurridos desde Jueves 1 de enero de 1970 es 18.718.
    18.718 dividido por 7 es 2.674 con resto 0.
    Esto significa que el 1 de abril de 2021 es exactamente 2674 semanas después Jueves 1 de enero de 1970. Debido a que la fecha es 0 días después Jueves, el día de la semana debe ser Jueves.
    En otras palabras, el día de la semana es siempre Jueves cuando el número de días transcurridos desde el 1 de enero de 1970 se divide por 7 y el resto es 0.
  • Si ingresa el 2 de abril de 2021:
    El número de días transcurridos desde Jueves 1 de enero de 1970 es 18.719.
    18.719 dividido por 7 es 2.674 con resto 1.
    Esto significa que el 2 de abril de 2021 son 2.674 semanas y un día después Jueves 1 de enero de 1970. Debido a que la fecha es un día después Jueves, el día de la semana debe ser Viernes.
    En otras palabras, el día de la semana es siempre Viernes cuando el número de días transcurridos desde el 1 de enero de 1970 se divide por 7 y el resto es 1.

En los ejemplos anteriores, el resto devuelto después de dividir el número de días transcurridos desde la época Unix por 7 se utiliza para encontrar el día de la semana de la siguiente manera.

A) Cuando el número de días transcurridos se divide por 7 y devuelve resto 0: Jueves
B) Cuando el número de días transcurridos se divide por 7 y devuelve residuo 1: Viernes
C) Cuando el número de días transcurridos se divide por 7 y devuelve resto 2: Sábado
D) Cuando el número de días transcurridos se divide por 7 y da como resultado resto 3: Domingo
E) Cuando el número de días transcurridos se divide por 7 y devuelve resto 4: Lunes
F) Cuando el número de días transcurridos se divide por 7 y da como residuo 5: Martes
G) Cuando el número de días transcurridos se divide por 7 y da como residuo 6: Miércoles

Sin embargo, las funciones de cálculo de Kintone no se pueden utilizar para encontrar residuos.
Por esta razón, en lugar de determinar el día de la semana directamente a partir del resto, el día de la semana se determina restando el valor del resto del número de días transcurridos y calculando un valor que sea divisible exactamente por 7.

Para calcular un valor que sea divisible por 7, el valor restante se devuelve como un número decimal, que luego se redondea al número entero más cercano utilizando la función ROUNDUP.

Cuando la diferencia de restar [(el número de días transcurridos - X) dividido por 7] del [cociente de dividir (el número de días transcurridos - X) por 7 redondeado a un número entero utilizando la función ROUNDUP] es 0, se determina que un valor es exactamente divisible por 7 (o, en otras palabras, tiene un resto de 0). El día de la semana se determina entonces de la siguiente manera.

A) Cuando el número de días transcurridos menos 0 se divide por 7 y devuelve resto 0: Jueves
B) Cuando el número de días transcurridos menos 1 se divide por 7 y devuelve resto 0: Viernes
C) Cuando el número de días transcurridos menos 2 se divide por 7 y devuelve resto 0: Sábado
D) Cuando el número de días transcurridos menos 3 se divide por 7 y devuelve resto 0: Domingo
E) Cuando el número de días transcurridos menos 4 se divide por 7 y devuelve resto 0: Lunes
F) Cuando el número de días transcurridos menos 5 se divide por 7 y devuelve resto 0: Martes
G) Cuando el número de días transcurridos menos 6 se divide por 7 y devuelve resto 0: Miércoles

Para obtener información sobre la función ROUNDUP., consulte la siguiente página.
Funciones ROUND, ROUNDUP y ROUNDDOWN: redondeo hacia abajo, hacia arriba y hacia abajo de valores numéricos